[AS3] Integer.reverseBytes() of Java.

Posted 2008/07/30 13:52 by wooyaggo

public function reverseBytes( value: int ): int
{
var num: int = ( ( value >>> 24 ) ) | ( ( value >> 8 ) & 0xFF00 ) | ( ( value << 8 ) & 0xFF0000

) | ( ( value << 24 ) );

return num;
}

Java 의 Integer.reverseBytes() 기능을 하는

ActionScript 3.0 버젼의 reverseBytes 입니다.

이올린에 북마크하기(0)

이올린에 추천하기(0)

Tag : 3.0, flash, reverseBytes

Filed under : ActionScript 3.0/유용한 소스

4 Comments Trackback

[AS3] ReflectingBitmapData 일반이미지를 비치는 이미지로~

Posted 2008/04/23 16:38 by wooyaggo

ReflectingBitmapData

-_-)/~

일반 이미지를 바닥에 비치는 이미지처럼 보여주는 클래스입니다.

맨날 바닥에 비치는 이미지 만들기 귀찮아서

이번에도 솔깃한 클래스 하나 올립니다 _(_ _)_

요즘 비치는 디자인이 많은데

요놈 한번~ 잡솨봐~

아주 쉽게 비치는 이미지를 사용할 수 있습니다.

사실 저도 컴퍼넌트로 만들려다가

하다보니 이렇게 쉽게 사용할 수 있을 줄은 몰랐습니다 -0-;;

딱 라이브러리에 있는 이미지의 Base Class 만 지정해주시면 됩니다. (맨 위 이미지)

아래 1/3 정도가 투명한 png 이미지

단, 주의하실 점은 이미지 자체가 아래 비치는 영역이 비어있어야합니다. (위 이미지처럼)

그렇지 않으면 아랫쪽 1/3 이 지워지고 그 부분에 비치는 영역이 생기게 됩니다.

우리 모두 고급 개발자가 되기위하여~~

p.s) 혹시 딴지거시는 분 있을까봐 알려드려용.

바닥에 바로 비치는 부분은 주변의 반사광으로 인해서 물체가 또렷하게 비치지 않습니다.

그렇기 때문에 바닥에 바로 닿는 부분은 잘 안보이고 갈수록 보이다가 끝으로 갈 수록 안보이게 되도록 제작했습니다.

멋지죠? 그렇다면 후원금 ㄱㄱ

소스 & 샘플 다운 받기

이미지 아래로 1/3 늘려주는 Photoshop CS3 용 Action 파일

(받아서 더블클릭하면 Action 이 추가됨, png 파일 열고 액션 돌리면 되겠죠?)

소스 보기

package kr.as3.component
{
   import flash.display.*;
   import flash.geom.*;

   /**
   * ReflectingBitmapData
   *
   * A base class of symbol is located in Symbol Library.
   *
   * @author: Yun Jinsang (a.k.a. Wooyaggo, http://www.as3.kr, victim4@gmail.com)
   * @created: 2008.04.23
   *
   * This source code follow LGPL (Lesser GPL)
   *


   * 본 제품(소프트웨어)는 GPL 라이센스 하에 배포되는 소프트웨어 PresentationKit 을 포함합니다


   *
   * 이 소스코드는 LGPL 을 따릅니다.
   * 사실 저도 LGPL 을 잘 모릅니다.
   *
   * 하지만 단순한 몇가지를 나열해봅니다.
   *
   * * 라이센시(Licensee)는 오픈소스 소프트웨어(이 컴퍼넌트 클래스)를 자유롭게 사용할 수 있다.
   * * 라이센시(Licensee)는 오픈소스 소프트웨어(이 컴퍼넌트 클래스)를 일정한 조건하에 자유롭게 복제할 수 있다.
   * * 라이센시(Licensee)는 오픈소스 소프트웨어(이 컴퍼넌트 클래스)를 일정한 조건하에 자유롭게 수정, 수정된 내용을 재배포할 수 있다.
   *
   * * 복제, 수정, 재배포에 대한 조건 *
   * * 저작권 관련 문구를 유지한다.
   * * 제품명 혹은 컴퍼넌트(클래스)명을 중복되지 않게 한다.
   * * 최종결과물에 사용 여부를 명시한다. (논문의 "인용" 과 비슷)
   * * 수정, 추가하였을때는 수정, 추가한 소스코드도 공개한다. (저작자에게 email 로 알리면 된다고 봄)
   * * 특허에 관련될 경우 복잡해지니 무시.
   *
   *
   * 간단하게 이야기하면 이 소스는 LGPL 을 따르기 때문에 사용했다는 것을 반드시 밝혀야하고,
   * 원본 소스가 수정 또는 추가되면 그 소스도 자동으로 LGPL 을 따르게 된다는 이야기입니다.
   *
   * 더 쉽게 말해서 걍 쓰시고 썼다는 이야기만 해주시면 될거 같습니다. 대부분 수정은 잘 안하자나요 ㅋㅋ
   * 수정하면 수정했다고 공개하거나 메일로 소스랑 같이 알려주면되는거 같구요.
   * 생각보다 그렇게 어려운 건 아닌거 같습니다^^
   *
   * 오픈소스 소프트웨어 라이센스 가이드 : http://wiki.kldp.org/wiki.php/OpenSourceLicenseGuide?action=show&redirect=FindPage#s-3.2.2
   * KLDP 의 LGPL 관련 질문글 : http://search.empas.com/search/oea/kldp/oe.html?q=LGPL&sdsn=&en=utf8
   *
   * 우리 모두 같이 자유롭게 소스를 공개하고 떳떳하게 사용하는 분위기를 조성해봅시다.
   *
   */
   public class ReflectingBitmapData extends BitmapData
   {
      private var SCALE: Number = -0.5;

      public function ReflectingBitmapData( width: int, height: int, transparent: Boolean = true, fillColor: uint = 0 )
      {
         super( width, height, transparent, fillColor );

         var length: int = int( 2 * this.height / 3 );
         var margin: int = this.height - length;

         this.fillRect( new Rectangle( 0, length, this.width, margin ), 0 );

         var scaleMatrix: Matrix = new Matrix();
         scaleMatrix.scale( 1, SCALE );

         var moveMatrix: Matrix = new Matrix();
         moveMatrix.translate( 0, ( length / SCALE ) - length );
         moveMatrix.concat( scaleMatrix );

         var tmpData: BitmapData = this.clone();

         this.draw( tmpData, moveMatrix );

         var gradientColor: Array =    [    0,       0,    0,    0,       0    ];
         var gradientAlpha: Array =    [    1,       0.1, 0.5, 0.7,    0    ];
         var gradientRatio: Array =    [    0,    1,       8,    10,    70    ];
         var gradientMatrix: Matrix = new Matrix();
         gradientMatrix.createGradientBox( this.width, this.height, Math.PI / 2, 0, length-1 );

         var gradientMask: Shape = new Shape();
         gradientMask.graphics.beginGradientFill( GradientType.LINEAR, gradientColor, gradientAlpha, gradientRatio, gradientMatrix, SpreadMethod.PAD );
         gradientMask.graphics.drawRect( 0, 0, this.width, this.height );
         gradientMask.graphics.endFill();

         var gradientData: BitmapData = new BitmapData( gradientMask.width, gradientMask.height, true, 0 );
         gradientData.draw( gradientMask, null, null, null, null, true );

         this.copyPixels( this, this.rect, new Point(), gradientData );

         tmpData.dispose();
         gradientData.dispose();
      }
   }
}

이올린에 북마크하기

Tag : as3, BitmapData, 비치는 이미지

Filed under : ActionScript 3.0/유용한 소스

14 Comments Trackback

[AS3] 포토샵 선택툴 효과

Posted 2008/03/10 10:59 by wooyaggo

지금 만드는 캡쳐플그램에 쓸일이 있어서

평소 만들어보고 싶었는데

의외로 이쁘게 만들어졌네요.^^

그릴 영역을 Rectangle 클래스로 설정하고

SelectionLayer.draw( rect ); 로 동작해주시면 됩니다.

SelectionLayer.as 소스보기

package
{
   import flash.display.Bitmap;
   import flash.display.BitmapData;
   import flash.display.Sprite;
   import flash.events.TimerEvent;
   import flash.geom.Rectangle;
   import flash.utils.Timer;

   /**
   * 선택 영역 효과 레이어.
   *
   * @author http://www.as3.kr
   * @author Wooyaggo ( victim4@gmail.com )
   *
   */
   public class SelectionLayer extends Sprite
   {
      private var bitmap: Bitmap;
      private var bitmapData: BitmapData;

      private var timer: Timer;

      public function SelectionLayer()
      {
         this.bitmapData = new BitmapData( 10, 10, true, 0 );

         this.bitmap = new Bitmap( this.bitmapData );
         this.addChild( this.bitmap );

         this.timer = new Timer( 50 );
         this.timer.addEventListener( TimerEvent.TIMER, onTimer );
      }

      private var padding: int = 0;
      private const GAP: int = 4;
      public function draw( selection: Rectangle ): void
      {
         // reset
         this.bitmapData.dispose();
         this.bitmapData = new BitmapData( selection.width, selection.height, true, 0 );
         this.bitmap.bitmapData = this.bitmapData;

         this.bitmap.x = selection.x;
         this.bitmap.y = selection.y;

         this.drawLine();

         this.timer.start();
      }

      private function onTimer( e: TimerEvent ): void
      {
         this.repeat();
      }

      public function repeat(): void
      {
         this.padding++;
         this.padding %= 2 * GAP;

         this.drawLine();
      }

      private var lineColor: Number = 0xFF000000;
      private var lineColor2: Number = 0xFFFFFFFF;
      private function drawLine(): void
      {
         this.bitmapData.fillRect( this.bitmapData.rect, 0 );

         var rect: Rectangle;
         var loop: int;

         rect = new Rectangle( padding - ( 2 * GAP ), 0, GAP, 1 );
         loop = 1 + this.bitmapData.width / ( GAP * 2 );
         do
         {
            this.bitmapData.fillRect( rect, lineColor );
            rect.x += GAP;
            this.bitmapData.fillRect( rect, lineColor2 );
            rect.x += GAP;
         }while( loop-- )

         rect = new Rectangle( 0, padding - ( 2 * GAP ), 1, GAP );
         loop = 1 + this.bitmapData.height / ( GAP * 2 );
         while( loop-- )
         {
            this.bitmapData.fillRect( rect, lineColor );
            rect.y += GAP;
            this.bitmapData.fillRect( rect, lineColor2 );
            rect.y += GAP;
         }

         var margin: int;

         margin = padding - ( this.bitmapData.width % ( 2 * GAP ) ) + 1;

         rect = new Rectangle( margin - ( 2 * GAP ), this.bitmapData.height - 1, GAP, 1 );
         loop = 1 + this.bitmapData.width / ( GAP * 2 );
         do
         {
            this.bitmapData.fillRect( rect, lineColor );
            rect.x += GAP;
            this.bitmapData.fillRect( rect, lineColor2 );
            rect.x += GAP;
         }while( loop-- )

         margin = padding - ( this.bitmapData.height % ( 2 * GAP ) ) + 1;

         rect = new Rectangle( this.bitmapData.width - 1, margin - ( 2 * GAP ), 1, GAP );
         loop = 1 + this.bitmapData.height / ( GAP * 2 );
         while( loop-- )
         {
            this.bitmapData.fillRect( rect, lineColor );
            rect.y += GAP;
            this.bitmapData.fillRect( rect, lineColor2 );
            rect.y += GAP;
         }
      }
   }
}

사용예입니다. ( 패키지명 맞춰서 1 frame 에 붙여서 테스트하시면 됩니다. )

import com.display.SelectionLayer

var selection: SelectionLayer = new SelectionLayer();
addChild( this.selection );

var rect: Rectangle = new Rectangle( 0, 0, 200, 200 );
this.selection.draw( rect );
this.selection.x = this.selection.y = 50;

SelectionLayer.as

[ 소스 받기 ]

이올린에 북마크하기

Tag : 3.0, as3, flash, selection, 선택툴, 플래시

Filed under : ActionScript 3.0/유용한 소스

12 Comments Trackback

[AS3] XMLLoader 클래스.

Posted 2008/03/07 17:48 by wooyaggo

기존의 URLLoader 의 경우

한상훈님의 말씀에 의하면

euc-kr 로 인코딩되어 있는 파일에서

4000 자가 넘는 xml 파일의 경우 파싱 에러가 난다고 합니다.

저 역시도 한글 파일의 내부 파서 오류때문에

엄청나게 고생했었습니다.

그래서 URLLoader 가 아니라

URLStream 으로 읽어들여 직접 "euc-kr" 로 읽어와서

XML 로 파싱하는 방법으로 해결하였습니다.

아래는 XMLLoader 클래스의 주요 소스입니다.

override protected function loadComplete( e: Event ): void
{
   try
   {
      this._xml = XML( this.loader.readMultiByte( this.loader.bytesAvailable, this.encode ) );
   }
   catch( e: TypeError )
   {
      this.dispatchEvent( new XMLLoaderEvent( XMLLoaderEvent.LOAD_FAIL, "parse error" ) );
      return;
   }

   this.dispatchEvent( new XMLLoaderEvent( XMLLoaderEvent.LOAD_COMPLETE ) );
}

위에서 보시다시피 URLStream.readMultiByte 로 직접 텍스트를 가져옵니다.

인코딩 타입은 기본으로 utf-8 로 잡혀있지만

XMLLoader.encode 라는 변수에 직접 euc-kr 또는 ascii 로 설정하실 수 있습니다.

아래는 euc-kr 로 작성된 파일을 URLLoader 와 XMLLoader 를 실험해놓은 페이지 입니다.

URLLoader : http://www.as3.kr/URLLoader/

XMLLoader : http://www.as3.kr/XMLLoader/

위 실험에서 URLLoader 는 50% 확률로 XML 이 오류가 나는 반면

XMLLoader 는 에러가 나지 않는 것을 보실 수 있습니다.

테스트에 사용된 소스와 관련 소스를 첨부합니다.

XMLLoader.zip

다운로드

이올린에 북마크하기

Tag : 3.0, as3, TIP, URLLoader, XMLLoader

Filed under : ActionScript 3.0/유용한 소스

9 Comments 1 Trackback

[AS3] CustomTextMotion

Posted 2007/10/12 15:49 by wooyaggo

flex_com.swc

Flex 용 swc 컴포넌트

flash_com.swc

Flash CS3 용 swc 컴포넌트

- 샘플 -

사용방법 :

1) Flex 용 swc 컴퍼넌트
- Flash 로만 작업하면 필요 없음
- Project 우클릭 > Properties > ActionScript Build Path > Library path > Add SWC > 파일 선택
- 사용 ㄱㄱ

2) Flash CS3 용 swc 컴퍼넌트
- Flex 로만 작업하면 필요 없음
- C:\Users\우야꼬\AppData\Local\Adobe\Flash CS3\en\Configuration\Components (사용자 계정. 예는 vista)
- Flash CS3 용 swc 컴퍼넌트 복사
- 플래시 창에서 Components 패널 reload.
- Library 로 com_motion 컴퍼넌트를 추가한다.
- 사용 ㄱㄱ

사용 예제

package AS
{
   import com.motion.*;

   import flash.display.Sprite;
   import flash.events.MouseEvent;
   import flash.text.*;

   public class CustomTextMotionSample extends Sprite
   {
      private var motion:CustomTextMotion;

      private var txt:TextField;

      public function CustomTextMotionSample()
      {
         this.createText();

         this.motion = new CustomTextMotion();
         this.motion.target = this.txt;

         this.stage.addEventListener(MouseEvent.CLICK, click);
      }

      private function click(e:MouseEvent):void
      {
         this.motion.start();
      }

      private function createText():void
      {
         this.txt = new TextField();
         this.txt.defaultTextFormat = new TextFormat("Tahoma", 10);
         this.txt.text = "com.motion.CustomTextMotion Sample";
         // Left
         this.txt.autoSize = TextFieldAutoSize.LEFT;
         this.txt.x = (this.stage.stageWidth - this.txt.width)/2;
         this.txt.y = (this.stage.stageHeight - this.txt.height)/2;

         this.addChild(this.txt);
      }
   }
}

추가 설정 예제

- 모션 진행 방향
- 랜덤 텍스트 캐릭터 세트 설정. (영문, 특수문자, 영문+특수문자, 한글(비츄))
- 모션 시간 (ms)
- 이벤트 (시작, 변할때마다, 끝)

package AS
{
   import com.motion.*;

   import flash.display.Sprite;
   import flash.events.MouseEvent;
   import flash.text.*;

   public class CustomTextMotionSample extends Sprite
   {
      private var motion:CustomTextMotion;

      private var txt:TextField;

      public function CustomTextMotionSample()

   {
         this.createText();

         this.motion = new CustomTextMotion();
         this.motion.target = this.txt;

         // CustomTextEvent : START, STOP, UPDATE
         this.motion.addEventListener(CustomTextEvent.START, onStart);
         this.motion.addEventListener(CustomTextEvent.STOP, onStop);
         this.motion.addEventListener(CustomTextEvent.UPDATE, onUpdate);

         // CustomTextSet : ENGLISH, ESCAPE, ENGLISH_ESCAPE, KOREAN(not recommand).
         this.motion.character = CustomTextSet.ENGLISH_ESCAPE;

         // CustomTextDirection : LEFT, RIGHT
         this.motion.direction = CustomTextDirection.RIGHT;

         // Delay (ms)
         this.motion.time = 5000;

         this.stage.addEventListener(MouseEvent.CLICK, click);
      }

      private function click(e:MouseEvent):void
      {
         this.motion.start();
      }

      private function onStart(e:CustomTextEvent):void
      {
         trace("start");
      }

      private function onStop(e:CustomTextEvent):void
      {
         trace("stop");
      }

      private function onUpdate(e:CustomTextEvent):void
      {
         trace("update");
      }

      private function createText():void
      {
         this.txt = new TextField();
         this.txt.defaultTextFormat = new TextFormat("Tahoma", 10);
         this.txt.text = "com.motion.CustomTextMotion Sample";
         // Right
         this.txt.autoSize = TextFieldAutoSize.RIGHT;
         this.txt.x = (this.stage.stageWidth - this.txt.width)/2;
         this.txt.y = (this.stage.stageHeight - this.txt.height)/2;

         this.addChild(this.txt);
      }
   }
}

이올린에 북마크하기

Tag : 3.0, as3, custom, flash, random text, 소스, 플래시

Filed under : ActionScript 3.0/유용한 소스

2 Comments Trackback

[Javascript] 기본 Flash Embed 소스

Posted 2007/09/19 11:43 by wooyaggo

// reEmbed.js
function reEmbed(str){ document.write(str) }

// at html

<script language="javascript" src="http://pro.dmikorea.co.kr/reEmbed.js"></script>
<script language="javascript">



var swf_src = "CGMFlvPlayer.swf";
var swf_width = "406";
var swf_height = "366";
var swf_version = "9.0.47.00";
var swf_id = (tmp = swf_src.split("/"), tmp = tmp[tmp.length - 1], tmp.split(".swf").shift());
var swf_fullscreen = "true";
var swf_script = "always";
var swf_wmode = "window";
var swf_networking = "all";
var swf_bgcolor = "";
var swf_vars = "cid=1234&skin=pink"; // pink, gray, purple, black
var nocache = Math.random()*3600000;
reEmbed('<object classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000" codebase="http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version='+swf_version+'" name="'+swf_id+'" width="'+swf_width+'" height="'+swf_height+'" id="'+swf_id+'"> <param name="movie" value="'+swf_src+'?nocache='+nocache+'" /> <param name="quality" value="high" /> <param name="allowFullScreen" value="'+swf_fullscreen+'" /> <param name="bgColor" value="' + swf_bgcolor + '" /> <param name="allowScriptAccess" value="'+swf_script+'" /> <param name="allowNetworking" value="'+swf_networking+'" /> <param name="wmode" value="'+swf_wmode+'" /> <param name="FlashVars" value="'+swf_vars+'" /> <embed src="'+swf_src+'?nocache='+nocache+'" allowFullScreen="'+swf_fullscreen+'" FlashVars="'+swf_vars+'" allowScriptAccess="'+swf_script+'" allowNetworking="'+swf_networking+'" width="'+swf_width+'" height="'+swf_height+'" quality="high" pluginspage="http://www.macromedia.com/go/getflashplayer" type="application/x-shockwave-flash" name="'+swf_id+'"></embed></object>');
</script>