[AS3] Away3D 예제.

2008.09.17 11:47

Away3D 예제. [ 다운로드 ]

HoverCamera3D, PhongColorMaterial, DirectionalLight3D 연습 예제.

package
{
/*****************************************************************
   * Description    : Away3D Phong & Light Example
   * Class Name    : SampleAway3D ( Document Class )
   * Linkage FLA    : SampleAway3D.fla
   * Extends       : Sprite
   * Company    : Belong to www.as3.kr.
   * Author       : JINSANG YUN ( a.k.a. Wooyaggo victim4@gmail.com )
   * Last modified : 2008-09-17
   *
   * Copyright www.as3.kr. All Rights Reserved.
   ******************************************************************/

import away3d.cameras.HoverCamera3D;
import away3d.containers.Scene3D;
import away3d.containers.View3D;
import away3d.core.render.Renderer;
import away3d.lights.DirectionalLight3D;
import away3d.materials.PhongColorMaterial;
import away3d.primitives.Cube;

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

public class SampleAway3D extends Sprite
   {
   // primitive elements, scene, camera and view.
   private var view: View3D;
   private var scene: Scene3D;
   private var camera: HoverCamera3D;

   private var cube: Cube;
   private var light: DirectionalLight3D;

   public function SampleAway3D()
      {
      this.initScene();
      this.initCamera();
      this.initView();
      this.initObjects();
      this.initLights();

      this.initListeners();
      }

   private function initScene(): void
      {
      // create default scene.
      this.scene = new Scene3D();
      }

   private function initCamera(): void
      {
      this.camera = new HoverCamera3D( { zoom: 3, focus: 100, distance: 100 } );
      this.camera.tiltangle = 40;
      this.camera.targettiltangle = 40;
      this.camera.mintiltangle = -50;
      this.camera.maxtiltangle = 50;
      this.camera.yfactor = 1;
      this.camera.steps = 7;
      }

   private function initView(): void
      {
      // create view with scene and camera.
      this.view = new View3D( { scene: this.scene, camera: this.camera } );
      this.view.x = this.stage.stageWidth/2;
      this.view.y = this.stage.stageHeight/2;

      this.addChild( this.view );
      }

   private function initObjects(): void
      {
      // create cube have a phong material.
      this.cube = new Cube( { material: new PhongColorMaterial( { color: 0xCCCCCC, specular: 0.6 } ) } );
      this.scene.addChild( this.cube );
      }

   private function initLights(): void
      {
      // create and locate light.
      this.light = new DirectionalLight3D( { color: 0xFFFFFF, ambient: 0.25, diffuse: 0.75, specular: 0.9 } );
      this.light.x = 40000;
      this.light.z = 40000;
      this.light.y = 40000;
      this.scene.addChild( this.light );
      }

   private function initListeners(): void
      {
      this.stage.addEventListener( MouseEvent.MOUSE_DOWN, dragStart );
      this.stage.addEventListener( MouseEvent.MOUSE_UP, dragStop );

      this.stage.addEventListener( Event.ENTER_FRAME, enterFrame );
      }

   private function enterFrame( e: Event ): void
      {
      this.camera.hover();

      this.light.x = this.camera.x;
      this.light.y = this.camera.y;
      this.light.z = this.camera.z;

      this.view.render();
      }

   private function dragStart( e: MouseEvent ): void
      {
      this.lastx = this.view.mouseX;
      this.lasty = this.view.mouseY;

      this.stage.addEventListener( Event.ENTER_FRAME, drag );
      }

   private function dragStop( e: MouseEvent ): void
      {
      this.stage.removeEventListener( Event.ENTER_FRAME, drag );
      }

   private const DRAG_RATING: Number = 0.5;
   private var dragx: Number;
   private var dragy: Number;
   private var lastx: Number;
   private var lasty: Number;
   private function drag( e: Event ): void
      {
      this.dragx = this.view.mouseX - lastx;
      this.dragy = this.view.mouseY - lasty;

      this.lastx = this.view.mouseX;
      this.lasty = this.view.mouseY;

      this.camera.targetpanangle += this.dragx * DRAG_RATING;
      this.camera.targettiltangle += this.dragy * DRAG_RATING;
      }
   }
}

저작자표시비영리동일조건

'ActionScript 3.0 > 내가 만든 플래시' 카테고리의 다른 글

[AS3] 이런 맛에 개발하는게 아닐까요? (19)	2009.02.25
[AS3] 우야꼬와 채팅을~ / Talk with Wooyaggo (16)	2008.09.20
[AS3] Away3D 예제. (7)	2008.09.17
TagCloud 를 만들어 봤습니다. (14)	2008.06.20
[AS3] Background Fading (10)	2008.05.28
[AS3] Browser History 연동 Flash (6)	2008.05.07

금도리 2008.09.17 18:09

조명이 내리 쬐는 박스가 돌아가네여...ㅋㅋ

# Delete Reply
- 우야꼬　 2008.09.18 21:43 신고
  
  사실은 박스는 그대로고 라이트랑 카메라가 돌아가는거라능 ㅋㅋ
  
  # Delete
검쉰 2008.09.18 18:02 신고

Alway3D 한번도 안해봤어요 ㅎㅎ

# Delete Reply
- 우야꼬　 2008.09.18 21:44 신고
  
  검쉰님은 금방하실듯 ㅋ
  
  # Delete
Han Sanghun 2008.09.18 22:23

모서리 쪽으로 가면 조명이 이상하다는...

# Delete Reply
- 우야꼬　 2008.09.18 23:47 신고
  
  세그먼트 두개짜리에요 ㅋㅋ
  상훈형때문에라도 건성으로 못하겟어요 ㅋ
  
  # Delete
매력덩어리 2011.04.12 09:40

우야꼬님~
camera.targetpanangle
camera.targettiltangle
저는 왜 카메라에 이런 속성들이 없다고 나올까요??
우야꼬님 예제로는 실행이 되는데
같은 식을 복사해서 새로 만들면 오류가 뜨네요...
this.camera.tiltangle = 40;
this.camera.targettiltangle = 40;
this.camera.mintiltangle = -50;
this.camera.maxtiltangle = 50;
이것들도 다 안먹습니다...

# Delete Reply

PREV 1 2 3 4 5 6 7 8 9 10 ···16 NEXT

Flash Game Dev :: Starling & Mobile

[AS3] Away3D 예제.

'ActionScript 3.0 > 내가 만든 플래시' 카테고리의 다른 글

+ Recent posts