ByteArray를 String으로 변환해서 써보자.

ActionScript 3.0/내가 만든 플래시

ByteArray를 String으로 변환해서 써보자.

우야꼬　 2009. 4. 3. 04:25

ByteArray 타입의 바이너리 데이터를

웹에서 사용할 수 있는 문자열로 변환해줍니다.

아래의 1번 예제는

1. 유저의 이미지를 불러와 Bitmap.draw() 로 찍은 후에

2. JPEncoder 를 통해서 ByteArray로 인코딩을 합니다.

3. 이렇게 인코딩된 ByteArray를 텍스트로 변환합니다.

4. 텍스트를 클립보드로 복사합니다. (ctrl + c)

2번 예제는

1. 입력된(ctrl + v ) 텍스트를 읽어와서

2. ByteArray로 다시 변환합니다.

3. 이렇게 변환된 ByteArray를 다시 Loader를 이용해서 이미지로 로드해옵니다.

1) Binary -> Text

2) Text -> Binary

사용법은 간단합니다.

ByteArray를 텍스트로 변환하려면

var text: String = new StringSerializer().serialize( byte );

텍스트를 ByteArray로 다시 변환하려면

var byte: ByteArray = new StringSerializer().unserialize( text );

이렇게 사용하면 됩니당.

에러가 간혹 있을 수도 있습니다. 에러같은거 보이시면 바로 댓글 ㄱㄱ

package kr.as3.byte
{
     import flash.utils.ByteArray;

     public class StringSerializer
     {
          private const PRESET: Array = [ "V", "e", "z", "h", "E", "2", "g", "Y", "=", "S", "t", "_", "Z", "c", "3", "7", "8", "X", "P", "6", "m", "i", "H", "T", "n", "k", "B", "D", "+", "l", "5", "p", "1", "r", "f", "w", "G", "a", "o", "M", "A", "R", "9", "s", "x", "y", "W", "b", "N", "0", "K", "L", "u", "I", "Q", "F", "C", "O", "-", "U", "q", "d", "v", "4" ];

          public function serialize( $data: ByteArray, compress: Boolean = true ): String
          {
               var str: String = "";

               var data: ByteArray = new ByteArray();
               data.writeBytes( $data );

               if( compress == true )
                    data.compress();

               data.position = 0;

               var i: int = 0;
               var len: int = int( data.length / 3 );
               var padding: int = data.length - ( len * 3 );
               var byte: uint;

               str = PRESET[ padding ];

               for( i ; i < len ; i += 1 )
               {
                    byte = ( data.readUnsignedByte() << 16 ) + ( data.readUnsignedByte() << 8 ) + data.readUnsignedByte();
                    str += serialize3Byte( byte );
               }

               if( padding == 1 )
               {
                    byte = ( data.readUnsignedByte() << 16 );
                    str += serialize3Byte( byte );
               }
               else if( padding == 2 )
               {
                    byte = ( data.readUnsignedByte() << 16 ) + ( data.readUnsignedByte() << 8 );
                    str += serialize3Byte( byte );
               }

               return str;
          }

          public function unserialize( $string: String, compressed: Boolean = true ): ByteArray
          {
               var data: ByteArray = new ByteArray();

               var padding: int = PRESET.indexOf( $string.charAt( 0 ) );

               var i: int = 0;
               var len: int = int( $string.length / 4 );
               len -= padding == 0 ? 0 : 1;
               var byte: uint;

               for( i ; i < len ; i += 1 )
               {
                    byte = unserialize4String( $string.slice( i*4 + 1, i*4 + 5 ) );
                    data.writeByte( ( byte >> 16 ) & 0xFF );
                    data.writeByte( ( byte >> 8 ) & 0xFF );
                    data.writeByte( byte & 0xFF );
               }

               if( padding == 1 )
               {
                    byte = unserialize4String( $string.slice( i*4 + 1, i*4 + 5 ) );
                    data.writeByte( ( byte >> 16 ) & 0xFF );
               }
               else if( padding == 2 )
               {
                    byte = unserialize4String( $string.slice( i*4 + 1, i*4 + 5 ) );
                    data.writeByte( ( byte >> 16 ) & 0xFF );
                    data.writeByte( ( byte >> 8 ) & 0xFF );
               }

               if( compressed == true )
                    data.uncompress();

               return data;
          }

          private const BITS: uint = 0x3F;

          private function serialize3Byte( bytes: uint ): String
          {
               var str: String = PRESET[ ( bytes >> 18 ) & BITS ] + PRESET[ ( bytes >> 12 ) & BITS ] + PRESET[ ( bytes >> 6 ) & BITS ] + PRESET[ bytes & BITS ];

               return str;
          }

          private function unserialize4String( str: String ): uint
          {
               var value: uint = ( uint( PRESET.indexOf( str.charAt( 0 ) ) ) << 18 ) + ( uint( PRESET.indexOf( str.charAt( 1 ) ) ) << 12 ) + ( uint( PRESET.indexOf( str.charAt( 2 ) ) ) << 6 ) + uint( PRESET.indexOf( str.charAt( 3 ) ) );

               return value;
          }
     }
}

데이터의 증감률은 테스트해보니 아래처럼 나왔습니다.

13,624 byte 가 17,313(34,626 byte)의 문자로 변환 약 254% 증가.

10,862 byte 가 13,293(26,586 byte)의 문자열로 변환 약 248% 증가.

대략 2.5배 정도 용량이 늘어나더군요.

64개의 문자를 가지고 6 bit 단위로 치환하는 방식이기 때문에 모두 웹에서 표현할 수 있는 문자열입니다.

그리고 Preset 도 지정할 수 있어서 활용하기 좋을거 같습니다.

잇힝~

p.s) XML에 이미지가 들어가는 티스토리의 백업기능을 보고 흉내내봤습니다.

저작자표시 비영리 동일조건